RS-485 master/slave 통신하기 - 소스코드 포함

https://yonglimlee.tistory.com/entry/485-Serial-%ED%86%B5%EC%8B%A0%ED%95%98%EA%B8%B0?category=734072

 

485 Serial 통신하기

1. 통신 방법

- RS-485

 

2. 구성

- master node 1개

- slave node 2개

 

3. master측 소스

#include "Definition.h" //구조체가 선언
#define MAX_FAIL_CNT 2

int t = 0;
//Slave 노드의 아이디이며
//Slave 노드는 각자의 아이디값이 달리해서 저장되어있음.
int id[NODE_CNT] = {101, 102}; 
int curIdx = 1;
enum eNode {e101=0, e102};

char ch = 'a';
//시리얼 통신 데이터 시작 문자열
char chAt = '@';
//시리얼 통신 데이터 종료 문자열
char chExclam = '!';

char buf[BUFFER_SIZE] = {0, };
char reqID[5] = {0, };
String str = "";
bool bTransmitt = false;
bool bRead = false;
int failCnt = 0;

//slave 노드로 부터 수신하는 값
enum envData {eTemp, eHumidity, eWater, eLight, eCnt};

unsigned long reqTime = 0;
unsigned long curTime = 0;

DATA nodes[NODE_CNT] = {0x00, };

//받은 데이터를 파싱하여 저장하는 함수
void parseDataFromPkt(String str)
{
  char* token = NULL;
  char tok[] = ",";
  float arrValue[eCnt] = {0,};
  DATA node = {0x00, };

  char pkt[BUFFER_SIZE] = {0, };
  strcpy(pkt, str.c_str());
  
  token = strtok(pkt, tok);
  int thisId = atoi(token);
  
  int i = 0;
  while(token != NULL && i < eCnt)
  {
    token = strtok(NULL, tok);
    arrValue[i] = atof(token);
    i++;
  }
  token = NULL;
  //파싱한후 배열에 저장
  node.head.id           = thisId;
  node.body.temperature  = arrValue[eTemp];
  node.body.humidity     = arrValue[eHumidity];
  node.body.water        = 0;
  node.body.light        = arrValue[eLight];
  if ( thisId == 101)
    nodes[e101] = node;
  else if (thisId = 102)
    nodes[e102] = node;
}


void setup() {
  // put your setup code here, to run once:
  Serial.begin(9600); // 직렬 통신 초기화
  Serial.println("I am a master!");
  delay(100);
  
  Serial.print("Slave node ID is ");
  for(int i = 0 ; i < NODE_CNT ; ++i)
  {
   Serial.print(id[i]);
   Serial.print(", ");
  }
  Serial.println("\nMaster node start...");
  Serial.setTimeout(5000);

}

void loop() {
  curTime = millis()/1000;
  //처음에 bTransmitt은 false로 초기화되어있음.
  if(bTransmitt == false){
    int cnt = curIdx%2;
	//@101! or @102!의 형식으로 slave id 요청
    sprintf(buf, "@%d!", id[cnt]);
    Serial.write(buf);
    bTransmitt = true;
    reqTime = millis()/1000;
  }

  if(bTransmitt == true && curTime - reqTime > 5){
    bTransmitt = false;
    curIdx++;
  }
  
  if(Serial.available())
  {
    char ch = Serial.read();
    //응담이 @으로 시작하면 SerialRead 읽기 시작
   if (ch == '@')
   {
    bRead = true;
   }
   else
   {
     //마지막 '!'를 문자를 받으면 
     //string 변수에 저장된 값을 parsing하여 저장
     if (ch == '!')
     {
      bRead = false;
      parseDataFromPkt(str);
      str = "";
      bTransmitt = false;
      curIdx++;
      delay(30000);
     }
	 //수신된 데이터 계속해서 string 변수에 저장
     if(bRead)
     {
      str += ch;
     }
   }

  }

  if(curIdx == 10000){
    curIdx = 1;
  }
}

 

4. Slave노드 소스

#include <DHT.h>  // Including library for dht
#include <Timer.h>
//Slave NODE는 각각 다른 MYID 값을 가짐
//테스트시에는 101, 102값을 가지는 slave node2개로 테스트함.
#define MYID 101
#define HEADER_SIZE 4
#define DATA_SIZE 16
#define BUFFER_SIZE 30
#define LIGHT   A1      
#define WATER   A0

bool bRead = false;
String str = "";
char buf[BUFFER_SIZE] = {0, };

bool isMyId(char* pkt);

int water = 1;
int light = 0;
float hum = 0.0f;
float tem = 0.0f;

Timer t;

#define DHTPIN 12     // NodeMCU D7 Pin          //pin where the dht11 is connected
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

void readHumTem(void* context)
{
  hum = dht.readHumidity();
  tem = dht.readTemperature();
  light  = analogRead(LIGHT); 
  water = analogRead(WATER);
  if(water > 10 )
    water = 1;
  else
    water = 0;
  
  if( isnan(hum) || isnan(tem))
  {
    Serial.println("Failed to read data from DHT Sensor!!!");
    return;
  }

}

void setup()  
{
  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  Serial.print("Slave Id is ");
  Serial.println(MYID);

  //온습도센서 초기화
  dht.begin();
  Serial.print("DHT is beginning...");
  delay(10);

  //환경데이터는 master node의 요청에 대한 응답과는 별개로
  //1초마다 한번씩 전역변수 값을 갱신함.
  t.every(1000, readHumTem, 0);
  
}
 
void loop() // run over and over
{
  if(Serial.available())
  {
    char ch = Serial.read();
    
    //'@'값을 읽으면 Serial 값을 읽기 시작함.
    if(ch == '@')
    {
      bRead = true;
    }
    else
    {
      if (ch == '!')
      {
        bRead = false;
        //'!' 문자가 들어오면 읽기 중단.
        //현재 MYID와 수신된 시리얼데이터의 ID값과 비교하여 
        //같을 경우에 응답을 보냄.
        if( isMyId(str) == true )
        {
            memset(buf, 0x00, BUFFER_SIZE);
            char chTem[8] = {0, };
            char chHum[8] = {0, };
          
            dtostrf(tem, 5, 2, chTem);
            dtostrf(hum, 5, 2, chHum);
            sprintf(buf, "@%d,%s,%s,%d,%d!", MYID, chTem, chHum, water, light);
            Serial.write(buf);
        }
        str = "";
      }
      if(bRead)
      {
       str += ch;
      }
    }
  }
  //1초마다 환경데이터 읽기
  t.update();
}

bool isMyId(String s)
{
  char pkt[10] = {0,};
  strcpy(pkt, s.c_str());
  char* id = strtok(pkt, "!");
  int nId = atoi(id);
  bool bSame = false;
  if( MYID == nId)
    bSame = true;
  return bSame;
}